Add support for building with meson and add flatpak template

meson.build

@@ -0,0 +1,43 @@
+project(
+  'lemoa',
+  'rust',
+  version: '0.1.0',
+  meson_version: '>= 0.59',
+  license: 'GPL-3.0',
+)
+
+gnome = import('gnome')
+
+application_id = 'com.lemmy-gtk.lemoa'
+
+dependency('glib-2.0', version: '>= 2.66')
+dependency('gio-2.0', version: '>= 2.66')
+dependency('gtk4', version: '>= 4.0.0')
+
+glib_compile_resources = find_program('glib-compile-resources', required: true)
+glib_compile_schemas = find_program('glib-compile-schemas', required: true)
+desktop_file_validate = find_program('desktop-file-validate', required: false)
+cargo = find_program('cargo', required: true)
+
+version = meson.project_version()
+
+prefix = get_option('prefix')
+bindir = prefix / get_option('bindir')
+
+datadir = prefix / get_option('datadir')
+pkgdatadir = datadir / meson.project_name()
+
+meson.add_dist_script(
+  'build-aux/dist-vendor.sh',
+  meson.project_build_root() / 'meson-dist' / meson.project_name() + '-' + version,
+  meson.project_source_root()
+)
+
+subdir('src')
+
+gnome.post_install(
+  gtk_update_icon_cache: true,
+  glib_compile_schemas: true,
+  update_desktop_database: true,
+)
+